string standalone.fn_SubmitSuspectSurvey_Webhook(String crmAPIRequest)
{
/* *******************************************************************************
	Function:       string standalone.fn_SubmitSuspectSurvey_Webhook(String crmAPIRequest)
	Label:          Fn - Submit Suspect Survey - Webhook
	Trigger:        Webhook when a suvey is submitted in Zoho Survey
	Purpose:		Push the calculated score and results from Analytics into the corresponding Zoho CRM record.
	Inputs:         String crmAPIRequest
	Outputs:        -

	Date Created:   2025-09-19 (Joel Lipman)
					- Initial release
					- Identifies a survey by email
	Date Modified:	2025-10-06 (Joel Lipman)
					- Clients wants a public URL for Survey: Need this webhook to create contact/account on-the-fly if needed.

	More Information:
					Within Zoho Surveys, configure the webhook to return the Response ID, Email, and Survey ID:
					1. Login to Zoho Surveys
					2. Click on the Survey > Builder > Hub > Triggers > Webhook > Manage
					3. Post URL is the REST API URL of the ZohoCRM function (this function)
					4. Set Request Body to JSON with name 'Survey' and within specify Response ID, Email, and Survey ID mapping as appropriate.
					5. Click on 'Save' button at the bottom of the page
					
					CAVEAT: If you have multiple contacts in your CRM with the same email address, then you're stuffed.

	******************************************************************************* */
	v_WebhookBody = ifnull(crmAPIRequest.toMap().get("body"),"");
	v_WebhookBodyDecode = zoho.encryption.urlDecode(v_WebhookBody);
	v_WebhookBodyString = v_WebhookBodyDecode.getSuffix("Survey=");
	m_SurveyBody = v_WebhookBodyString.toMap();
	//
	// find contact by email
	v_CrmContactID = "";
	l_SearchContacts = zoho.crm.searchRecords("Contacts","Email:equals:" + m_SurveyBody.get("Email"));
	for each  m_ContactResult in l_SearchContacts
	{
		//
		// if found then simply update the contact
		if(!isNull(m_ContactResult.get("id")))
		{
			v_CrmContactID = m_ContactResult.get("id");
			m_UpdateContact = Map();
			m_UpdateContact.put("Response_ID",m_SurveyBody.get("Response_ID"));
			m_UpdateContact.put("Survey_ID",m_SurveyBody.get("Survey_ID"));
			m_UpdateContact.put("Scheduled_Report_Generation_Time",zoho.currenttime.addHour(1).toString("yyyy-MM-dd'T'HH:mm:ss","Europe/London"));
			r_UpdateContact = zoho.crm.updateRecord("Contacts",m_ContactResult.get("id"),m_UpdateContact);
			info "Updating CRM Contact: " + r_UpdateContact;
		}
	}
	if(v_CrmContactID == "")
	{
		//
		// create an account/company record to associate the contact to
		v_CrmAccountID = "";
		if(!isNull(m_SurveyBody.get("Company")))
		{
			m_CreateAccount = Map();
			m_CreateAccount.put("Account_Name", m_SurveyBody.get("Company"));
			m_CreateAccount.put("Number_of_Employees", m_SurveyBody.get("Number_of_Employees"));
			m_CreateAccount.put("Turnover", m_SurveyBody.get("Last_Years_Turnover"));
			r_CreateAccount = zoho.crm.createRecord("Accounts", m_CreateAccount);
			info "Creating CRM Account: " + r_CreateAccount;
			if(!isNull(r_CreateAccount.get("id")))
			{
				v_CrmAccountID = r_CreateAccount.get("id");
			}
		}
		// create this contact as they filled in the survey without us sending it to them
		m_CreateContact = Map();
		m_CreateContact.put("First_Name", m_SurveyBody.get("First_Name"));
		m_CreateContact.put("Last_Name", m_SurveyBody.get("Last_Name"));
		m_CreateContact.put("Phone", m_SurveyBody.get("Phone"));
		m_CreateContact.put("Email", m_SurveyBody.get("Email"));
		m_CreateContact.put("Title", m_SurveyBody.get("Job_Title"));
		if(v_CrmAccountID != "")
		{
			m_CreateContact.put("Account_Name", v_CrmAccountID);
		}
		m_CreateContact.put("Response_ID",m_SurveyBody.get("Response_ID"));
		m_CreateContact.put("Survey_ID",m_SurveyBody.get("Survey_ID"));
		m_CreateContact.put("Scheduled_Report_Generation_Time",zoho.currenttime.addHour(1).toString("yyyy-MM-dd'T'HH:mm:ss","Europe/London"));	
		r_CreateContact = zoho.crm.createRecord("Contacts", m_CreateContact);
		info "Creating CRM Contact: " + r_CreateContact;
	}
	/* OPTIONAL: Send yourself an email
		sendmail
		[
			from :zoho.adminuserid
			to :"This email address is being protected from spambots. You need JavaScript enabled to view it."
			subject :"TEST: Survey has been submitted"
			message :crmAPIRequest
		]
	*/
	//
	// build response to Zoho Survey (hard-coded a ok)
	m_ResponseHeader = Map();
	m_ResponseHeader.put("status_code",200);
	return {"crmAPIResponse":m_ResponseHeader};
}

1.  string standalone.fn_SubmitSuspectSurvey_Webhook(String crmAPIRequest) 
2.  { 
3.  /* ******************************************************************************* 
4.      Function:       string standalone.fn_SubmitSuspectSurvey_Webhook(String crmAPIRequest) 
5.      Label:          Fn - Submit Suspect Survey - Webhook 
6.      Trigger:        Webhook when a suvey is submitted in Zoho Survey 
7.      Purpose:        Push the calculated score and results from Analytics into the corresponding Zoho CRM record. 
8.      Inputs:         String crmAPIRequest 
9.      Outputs:        - 
10.   
11.      Date Created:   2025-09-19 (Joel Lipman) 
12.                      - Initial release 
13.                      - Identifies a survey by email 
14.      Date Modified:    2025-10-06 (Joel Lipman) 
15.                      - Clients wants a public URL for Survey: Need this webhook to create contact/account on-the-fly if needed. 
16.   
17.      More Information: 
18.                      Within Zoho Surveys, configure the webhook to return the Response ID, Email, and Survey ID: 
19.                      1. Login to Zoho Surveys 
20.                      2. Click on the Survey > Builder > Hub > Triggers > Webhook > Manage 
21.                      3. Post URL is the REST API URL of the ZohoCRM function (this function) 
22.                      4. Set Request Body to JSON with name 'Survey' and within specify Response ID, Email, and Survey ID mapping as appropriate. 
23.                      5. Click on 'Save' button at the bottom of the page 
24.   
25.                      CAVEAT: If you have multiple contacts in your CRM with the same email address, then you're stuffed. 
26.   
27.      ******************************************************************************* */ 
28.      v_WebhookBody = ifnull(crmAPIRequest.toMap().get("body"),""); 
29.      v_WebhookBodyDecode = zoho.encryption.urlDecode(v_WebhookBody); 
30.      v_WebhookBodyString = v_WebhookBodyDecode.getSuffix("Survey="); 
31.      m_SurveyBody = v_WebhookBodyString.toMap(); 
32.      // 
33.      // find contact by email 
34.      v_CrmContactID = ""; 
35.      l_SearchContacts = zoho.crm.searchRecords("Contacts","Email:equals:" + m_SurveyBody.get("Email")); 
36.      for each  m_ContactResult in l_SearchContacts 
37.      { 
38.          // 
39.          // if found then simply update the contact 
40.          if(!isNull(m_ContactResult.get("id"))) 
41.          { 
42.              v_CrmContactID = m_ContactResult.get("id"); 
43.              m_UpdateContact = Map(); 
44.              m_UpdateContact.put("Response_ID",m_SurveyBody.get("Response_ID")); 
45.              m_UpdateContact.put("Survey_ID",m_SurveyBody.get("Survey_ID")); 
46.              m_UpdateContact.put("Scheduled_Report_Generation_Time",zoho.currenttime.addHour(1).toString("yyyy-MM-dd'T'HH:mm:ss","Europe/London")); 
47.              r_UpdateContact = zoho.crm.updateRecord("Contacts",m_ContactResult.get("id"),m_UpdateContact); 
48.              info "Updating CRM Contact: " + r_UpdateContact; 
49.          } 
50.      } 
51.      if(v_CrmContactID == "") 
52.      { 
53.          // 
54.          // create an account/company record to associate the contact to 
55.          v_CrmAccountID = ""; 
56.          if(!isNull(m_SurveyBody.get("Company"))) 
57.          { 
58.              m_CreateAccount = Map(); 
59.              m_CreateAccount.put("Account_Name", m_SurveyBody.get("Company")); 
60.              m_CreateAccount.put("Number_of_Employees", m_SurveyBody.get("Number_of_Employees")); 
61.              m_CreateAccount.put("Turnover", m_SurveyBody.get("Last_Years_Turnover")); 
62.              r_CreateAccount = zoho.crm.createRecord("Accounts", m_CreateAccount); 
63.              info "Creating CRM Account: " + r_CreateAccount; 
64.              if(!isNull(r_CreateAccount.get("id"))) 
65.              { 
66.                  v_CrmAccountID = r_CreateAccount.get("id"); 
67.              } 
68.          } 
69.          // create this contact as they filled in the survey without us sending it to them 
70.          m_CreateContact = Map(); 
71.          m_CreateContact.put("First_Name", m_SurveyBody.get("First_Name")); 
72.          m_CreateContact.put("Last_Name", m_SurveyBody.get("Last_Name")); 
73.          m_CreateContact.put("Phone", m_SurveyBody.get("Phone")); 
74.          m_CreateContact.put("Email", m_SurveyBody.get("Email")); 
75.          m_CreateContact.put("Title", m_SurveyBody.get("Job_Title")); 
76.          if(v_CrmAccountID != "") 
77.          { 
78.              m_CreateContact.put("Account_Name", v_CrmAccountID); 
79.          } 
80.          m_CreateContact.put("Response_ID",m_SurveyBody.get("Response_ID")); 
81.          m_CreateContact.put("Survey_ID",m_SurveyBody.get("Survey_ID")); 
82.          m_CreateContact.put("Scheduled_Report_Generation_Time",zoho.currenttime.addHour(1).toString("yyyy-MM-dd'T'HH:mm:ss","Europe/London")); 
83.          r_CreateContact = zoho.crm.createRecord("Contacts", m_CreateContact); 
84.          info "Creating CRM Contact: " + r_CreateContact; 
85.      } 
86.      /* OPTIONAL: Send yourself an email 
87.          sendmail 
88.          [ 
89.              from :zoho.adminuserid 
90.              to :"This email address is being protected from spambots. You need JavaScript enabled to view it." 
91.              subject :"TEST: Survey has been submitted" 
92.              message :crmAPIRequest 
93.          ] 
94.      */ 
95.      // 
96.      // build response to Zoho Survey (hard-coded a ok) 
97.      m_ResponseHeader = Map(); 
98.      m_ResponseHeader.put("status_code",200); 
99.      return {"crmAPIResponse":m_ResponseHeader}; 
100.  }