2. Home
  3. Articles
  4. CRM
  5. Zoho
  6. ZohoCRM: Get All eBay Active Listings

For Zoho Services only:


I'm actually part of something bigger at Ascent Business Solutions recognized as the top Zoho Premium Solutions Partner in the United Kingdom.

Ascent Business Solutions offer support for smaller technical fixes and projects for larger developments, such as migrating to a ZohoCRM.  A team rather than a one-man-band is always available to ensure seamless progress and address any concerns. You'll find our competitive support rates with flexible, no-expiration bundles at http://ascentbusiness.co.uk/zoho-support-2.  For larger projects, check our bespoke pricing structure and receive dedicated support from our hands-on project consultants and developers at http://ascentbusiness.co.uk/crm-solutions/zoho-crm-packages-prices.

The team I manage specializes in coding API integrations between Zoho and third-party finance/commerce suites such as Xero, Shopify, WooCommerce, and eBay; to name but a few.  Our passion lies in creating innovative solutions where others have fallen short as well as working with new businesses, new sectors, and new ideas.  Our success is measured by the growth and ROI we deliver for clients, such as transforming a garden shed hobby into a 250k monthly turnover operation or generating a +60% return in just three days after launch through online payments and a streamlined e-commerce solution, replacing a paper-based system.

If you're looking for a partner who can help you drive growth and success, we'd love to work with you.  You can reach out to us on 0121 392 8140 (UK) or info@ascentbusiness.co.uk.  You can also visit our website at http://ascentbusiness.co.uk.

ZohoCRM: Get All eBay Active Listings

Zoho
Hits: 1677
What?
Another one of these articles talking about getting all the active product listings from eBay for a specific client.

Why?
Our use-case scenario here is that we want to get an inventory level or stock check of all the products that are currently listed in a client's eBay store; we want to get the stock level and then use this data to synchronize with data held in Zoho Inventory...

How?
So we're going to use a ZohoCRM function to get this file which we can run on demand. Why not in Zoho Inventory or any other Zoho app? Because we like to challenge ourselves...

Once again, I'm not going into how to generate an access token / connection from Zoho to eBay, that is documented in my article: Zoho Creator: Push to eBay Listings

The megafunction
So I'm going to call this function "Fn - eBay - Get Active Products" and give it the internal name as "fn_GetEbayActiveProducts" without any arguments. Something to note in the below is that it asks you to set an estimated number of products that are in your listing, it will then generate the number of pages it thinks it has to loop, so try and give a number higher than the actual number of products you have in your shop, it will stop when it's reached the end of the list as per eBay and not what you might have thought it was.
copyraw 
/*
    Function: 		fn_GetEbayActiveProducts()
    Purpose: 		Queries eBay for all active listings
    Date Created:   2023-03-01 (Joel Lipman)
                    - Initial release
	Date Modified: 	????
					- ???
					
    More Info:
    - API Explorer Test Tool: 			https://developer.ebay.com/DevZone/build-test/test-tool/default.aspx?index=0&env=production&api=trading
    - GetMyeBaySelling Documentation: 	https://developer.ebay.com/devzone/xml/docs/reference/ebay/getmyebayselling.html
*/
//
// declare
v_Page = 1;
v_PerPage = 100;
l_Pages = List();
//
// specify page to start from
v_StartingPageIndex = 1;
//
// specify the maximum number of products you think you have on eBay
// the actual number will be less than this but this is for pagination estimates
v_MaximumProducts = 1500;
//
// now let's generate the page list to have all the available pages
v_TotalNumberOfPages = ceil(v_MaximumProducts / v_PerPage);
l_AddPages = leftpad(" ", v_TotalNumberOfPages).replaceAll(" ", ",").toList();
for each index v_Increment in l_AddPages
{
	l_Pages.add(v_StartingPageIndex + v_Increment);
}
v_TotalNumberOfPages = l_Pages.size();
//
// declare variables to store order details in a JSON or ZohoDeluge Map format
m_Response = Map();
l_JsonProducts = List();
//
// start preparing CSV file to email for export
v_ReportCSV = "ItemID,ItemName,Price,CurrencyCode,QuantityAvailable,SKU,DateCreated";
l_CsvFileRows = List();
l_CsvFileRows.add(v_ReportCSV);
//
// get access token 
v_AccessToken = standalone.fn_eBay_GetAccessToken();
//
v_TradingAPIVersion = 967;
v_Endpoint = "https://api.ebay.com/ws/api.dll";
//
// build header
m_Headers = Map();
m_Headers.put("X-EBAY-API-SITEID",3);
m_Headers.put("X-EBAY-API-COMPATIBILITY-LEVEL",v_TradingAPIVersion);
v_ApiCall = "GetMyeBaySelling";
m_Headers.put("X-EBAY-API-CALL-NAME",v_ApiCall);
m_Headers.put("X-EBAY-API-IAF-TOKEN",v_AccessToken);
//
// build params
m_Params = Map();
m_Params.put("WarningLevel","High");
m_Params.put("ErrorLanguage","en_GB");
m_Params.put("DetailLevel","ReturnAll");
//
// specify only the active list
m_ActiveList = Map();
m_ActiveList.put("Include",true);
m_ActiveList.put("ListingType","FixedPriceItem");
m_ActiveList.put("Sort","ItemID");
//
// exclude other lists
m_Exclude = Map();
m_Exclude.put("Include", false);
m_Params.put("DeletedFromSoldList",m_Exclude);
m_Params.put("DeletedFromUnsoldList",m_Exclude);
m_Params.put("ScheduledList",m_Exclude);
m_Params.put("SellingSummary",m_Exclude);
m_Params.put("SoldList",m_Exclude);
m_Params.put("UnsoldList",m_Exclude);
//
// select which fields to return
l_OutputFields = List();
l_OutputFields.add("ItemID");
l_OutputFields.add("Title");
l_OutputFields.add("SKU");
l_OutputFields.add("QuantityAvailable");
l_OutputFields.add("SellingStatus");
l_OutputFields.add("StartTime");
l_OutputFields.add("TotalNumberOfPages");
l_OutputFields.add("TotalNumberOfEntries");
m_Params.put("OutputSelector",l_OutputFields);
//
// now lets loop through a dynamic page list
for each v_Page in l_Pages
{
	//
	// specify which page
	m_Pagination = Map();
	m_Pagination.put("PageNumber",v_Page);
	m_Pagination.put("EntriesPerPage",v_PerPage);
	m_ActiveList.put("Pagination",m_Pagination);
	//
	m_Params.put("ActiveList",m_ActiveList);
	//
	// convert to xml and replace root nodes
	x_Params = m_Params.toXML();
	x_Params = x_Params.toString().replaceFirst("<root>","<?xml version=\"1.0\" encoding=\"utf-8\"?><" + v_ApiCall + "Request xmlns=\"urn:ebay:apis:eBLBaseComponents\">");
	x_Params = x_Params.toString().replaceFirst("</root>","</" + v_ApiCall + "Request>");
	// info "Request Sent to eBay:";
	// info x_Params;
	//
	// send the request XML as a string
	x_ResponseBody = invokeurl
	[
		url :v_Endpoint
		type :POST
		parameters:x_Params
		headers:m_Headers
	];
	if(v_Page==1)
	{
		//
		// get page results
		x_PaginationResult = x_ResponseBody.subString(x_ResponseBody.indexOf("<PaginationResult"),x_ResponseBody.lastIndexOf("</PaginationResult") + 19);
		v_TotalNumberOfProducts = x_PaginationResult.executeXPath("/PaginationResult/TotalNumberOfEntries/text()").toLong();
		//
		// determine total number of pages required
		v_TotalNumberOfPages = ceil(v_TotalNumberOfProducts / v_PerPage);
		info "Total Product(s): " + v_TotalNumberOfProducts;
		info "Total Page(s): " + v_TotalNumberOfPages;		
	}
	//
	// loop through products/items from response
	v_ItemNodePart = "Item";
	v_ItemNodeName = v_ItemNodePart + "Array";
	x_ItemNode = x_ResponseBody.subString(x_ResponseBody.indexOf("<" + v_ItemNodeName),x_ResponseBody.lastIndexOf(v_ItemNodeName) + v_ItemNodeName.length() + 1);
	l_Items = x_ItemNode.executeXPath("/" + v_ItemNodeName + "/" + v_ItemNodePart).toXmlList();
	for each  x_Item in l_Items
	{
		//
		// build JSON row
		m_Item = Map();
		m_Item.put("ItemID",x_Item.executeXPath("/" + v_ItemNodePart + "/ItemID/text()"));
		m_Item.put("ItemName",x_Item.executeXPath("/" + v_ItemNodePart + "/Title/text()"));
		m_Item.put("Price",x_Item.executeXPath("/" + v_ItemNodePart + "/SellingStatus/CurrentPrice/text()").toDecimal());
		m_Item.put("CurrencyCode",x_Item.executeXPath("/" + v_ItemNodePart + "/SellingStatus/CurrentPrice/@currencyID").executeXPath("/currencyID/text()"));
		m_Item.put("QuantityAvailable",x_Item.executeXPath("/" + v_ItemNodePart + "/QuantityAvailable/text()").toDecimal());
		m_Item.put("SKU",x_Item.executeXPath("/" + v_ItemNodePart + "/SKU/text()"));
		//
		v_Item_DateCreated = x_Item.executeXPath("/" + v_ItemNodePart + "/ListingDetails/StartTime/text()");
		v_Item_DateCreated = if(!isnull(v_Item_DateCreated),v_Item_DateCreated.getPrefix(".").replaceFirst("T"," ",true).toTime(),zoho.currenttime).toString("yyyy-MM-dd HH:mm:ssZ");
		m_Item.put("DateCreated",v_Item_DateCreated);
		//
		l_JsonProducts.add(m_Item);
		//
		// generate CSV row for monitoring purposes
		l_CsvFileRow = List();
		l_CsvFileRow.add("\"'" + x_Item.executeXPath("/" + v_ItemNodePart + "/ItemID/text()") + "\"");
		l_CsvFileRow.add("\"" + x_Item.executeXPath("/" + v_ItemNodePart + "/Title/text()") + "\"");
		l_CsvFileRow.add(x_Item.executeXPath("/" + v_ItemNodePart + "/SellingStatus/CurrentPrice/text()"));
		l_CsvFileRow.add(x_Item.executeXPath("/" + v_ItemNodePart + "/SellingStatus/CurrentPrice/@currencyID").executeXPath("/currencyID/text()"));
		l_CsvFileRow.add(x_Item.executeXPath("/" + v_ItemNodePart + "/QuantityAvailable/text()"));
		l_CsvFileRow.add("\"" + x_Item.executeXPath("/" + v_ItemNodePart + "/SKU/text()") + "\"");
		l_CsvFileRow.add(v_Item_DateCreated);
		//
		v_CsvRow = l_CsvFileRow.toString();
		l_CsvFileRows.add(v_CsvRow);	
	}	
	if(v_Page>=v_TotalNumberOfPages)
	{
		break;
	}
}
//
m_Response.put("items",l_JsonProducts);
//info m_Response;
//
// lets send the CSV and JSON by email
if(l_JsonProducts.size()>0)
{
	// 
	// generate a CSV list for monitoring purposes
	v_CSVFilename = "active-ebay-products-" + zoho.currenttime.toString("yyyy-MM-dd-HH-mm-ss") + ".csv";
	l_CsvFileRows.add("-----------------------------" + v_CSVFilename);
	//
	// usually \n works on some systems but this one works on systems that \n doesn't
	f_CSVFile = l_CsvFileRows.toString(zoho.encryption.urlDecode("%0A")).toFile(v_CSVFilename);
	//
	// just adding these in case
	v_JsonFilename = "active-ebay-products-" + zoho.currenttime.toString("yyyy-MM-dd-HH-mm-ss") + ".json";
	f_JsonFile = m_Response.toString().toFile(v_JsonFilename);
	// 
	// send via Email 
	v_CountRows = l_CsvFileRows.size() - 2;
	v_Subject = l_JsonProducts.size() + " eBay Products Export & Comparison";
	v_Message = "Hi there!<br /><br />Please find attached a log of <b>" + l_JsonProducts.size() + "</b> Product(s) from eBay that was exported on <b>" + zoho.currenttime.toString("EEEE, dd-MMM-yyyy") + "</b><br /><br />This is an automated email.  Please do not reply to it.<br /><br />Kind Regards,<br /><br />The Team";
	sendmail
	[
		from :zoho.adminuserid
		to :"Joel Lipman <This email address is being protected from spambots. You need JavaScript enabled to view it.>"
		subject :v_Subject
		message :v_Message
		Attachments :file:f_CSVFile,file:f_JsonFile
	]
}
//
return "Exported " + l_JsonProducts.size() + " product(s)";
  1.  /* 
  2.      Function:         fn_GetEbayActiveProducts() 
  3.      Purpose:         Queries eBay for all active listings 
  4.      Date Created:   2023-03-01 (Joel Lipman) 
  5.                      - Initial release 
  6.      Date Modified:     ???? 
  7.                      - ??? 
  8.   
  9.      More Info: 
  10.      - API Explorer Test Tool:             https://developer.ebay.com/DevZone/build-test/test-tool/default.aspx?index=0&env=production&api=trading 
  11.      - GetMyeBaySelling Documentation:     https://developer.ebay.com/devzone/xml/docs/reference/ebay/getmyebayselling.html 
  12.  */ 
  13.  // 
  14.  // declare 
  15.  v_Page = 1; 
  16.  v_PerPage = 100; 
  17.  l_Pages = List(); 
  18.  // 
  19.  // specify page to start from 
  20.  v_StartingPageIndex = 1; 
  21.  // 
  22.  // specify the maximum number of products you think you have on eBay 
  23.  // the actual number will be less than this but this is for pagination estimates 
  24.  v_MaximumProducts = 1500; 
  25.  // 
  26.  // now let's generate the page list to have all the available pages 
  27.  v_TotalNumberOfPages = ceil(v_MaximumProducts / v_PerPage); 
  28.  l_AddPages = leftpad(" ", v_TotalNumberOfPages).replaceAll(" ", ",").toList(); 
  29.  for each index v_Increment in l_AddPages 
  30.  { 
  31.      l_Pages.add(v_StartingPageIndex + v_Increment); 
  32.  } 
  33.  v_TotalNumberOfPages = l_Pages.size(); 
  34.  // 
  35.  // declare variables to store order details in a JSON or ZohoDeluge Map format 
  36.  m_Response = Map(); 
  37.  l_JsonProducts = List(); 
  38.  // 
  39.  // start preparing CSV file to email for export 
  40.  v_ReportCSV = "ItemID,ItemName,Price,CurrencyCode,QuantityAvailable,SKU,DateCreated"; 
  41.  l_CsvFileRows = List(); 
  42.  l_CsvFileRows.add(v_ReportCSV); 
  43.  // 
  44.  // get access token 
  45.  v_AccessToken = standalone.fn_eBay_GetAccessToken(); 
  46.  // 
  47.  v_TradingAPIVersion = 967; 
  48.  v_Endpoint = "https://api.ebay.com/ws/api.dll"; 
  49.  // 
  50.  // build header 
  51.  m_Headers = Map(); 
  52.  m_Headers.put("X-EBAY-API-SITEID",3); 
  53.  m_Headers.put("X-EBAY-API-COMPATIBILITY-LEVEL",v_TradingAPIVersion); 
  54.  v_ApiCall = "GetMyeBaySelling"; 
  55.  m_Headers.put("X-EBAY-API-CALL-NAME",v_ApiCall); 
  56.  m_Headers.put("X-EBAY-API-IAF-TOKEN",v_AccessToken); 
  57.  // 
  58.  // build params 
  59.  m_Params = Map(); 
  60.  m_Params.put("WarningLevel","High"); 
  61.  m_Params.put("ErrorLanguage","en_GB"); 
  62.  m_Params.put("DetailLevel","ReturnAll"); 
  63.  // 
  64.  // specify only the active list 
  65.  m_ActiveList = Map(); 
  66.  m_ActiveList.put("Include",true); 
  67.  m_ActiveList.put("ListingType","FixedPriceItem"); 
  68.  m_ActiveList.put("Sort","ItemID"); 
  69.  // 
  70.  // exclude other lists 
  71.  m_Exclude = Map(); 
  72.  m_Exclude.put("Include", false); 
  73.  m_Params.put("DeletedFromSoldList",m_Exclude); 
  74.  m_Params.put("DeletedFromUnsoldList",m_Exclude); 
  75.  m_Params.put("ScheduledList",m_Exclude); 
  76.  m_Params.put("SellingSummary",m_Exclude); 
  77.  m_Params.put("SoldList",m_Exclude); 
  78.  m_Params.put("UnsoldList",m_Exclude); 
  79.  // 
  80.  // select which fields to return 
  81.  l_OutputFields = List(); 
  82.  l_OutputFields.add("ItemID"); 
  83.  l_OutputFields.add("Title"); 
  84.  l_OutputFields.add("SKU"); 
  85.  l_OutputFields.add("QuantityAvailable"); 
  86.  l_OutputFields.add("SellingStatus"); 
  87.  l_OutputFields.add("StartTime"); 
  88.  l_OutputFields.add("TotalNumberOfPages"); 
  89.  l_OutputFields.add("TotalNumberOfEntries"); 
  90.  m_Params.put("OutputSelector",l_OutputFields); 
  91.  // 
  92.  // now lets loop through a dynamic page list 
  93.  for each v_Page in l_Pages 
  94.  { 
  95.      // 
  96.      // specify which page 
  97.      m_Pagination = Map(); 
  98.      m_Pagination.put("PageNumber",v_Page); 
  99.      m_Pagination.put("EntriesPerPage",v_PerPage); 
  100.      m_ActiveList.put("Pagination",m_Pagination); 
  101.      // 
  102.      m_Params.put("ActiveList",m_ActiveList); 
  103.      // 
  104.      // convert to xml and replace root nodes 
  105.      x_Params = m_Params.toXML(); 
  106.      x_Params = x_Params.toString().replaceFirst("<root>","<?xml version=\"1.0\" encoding=\"utf-8\"?><" + v_ApiCall + "Request xmlns=\"urn:ebay:apis:eBLBaseComponents\">"); 
  107.      x_Params = x_Params.toString().replaceFirst("</root>","</" + v_ApiCall + "Request>"); 
  108.      // info "Request Sent to eBay:"; 
  109.      // info x_Params; 
  110.      // 
  111.      // send the request XML as a string 
  112.      x_ResponseBody = invokeUrl 
  113.      [ 
  114.          url :v_Endpoint 
  115.          type :POST 
  116.          parameters:x_Params 
  117.          headers:m_Headers 
  118.      ]; 
  119.      if(v_Page==1) 
  120.      { 
  121.          // 
  122.          // get page results 
  123.          x_PaginationResult = x_ResponseBody.subString(x_ResponseBody.indexOf("<PaginationResult"),x_ResponseBody.lastIndexOf("</PaginationResult") + 19); 
  124.          v_TotalNumberOfProducts = x_PaginationResult.executeXPath("/PaginationResult/TotalNumberOfEntries/text()").toLong(); 
  125.          // 
  126.          // determine total number of pages required 
  127.          v_TotalNumberOfPages = ceil(v_TotalNumberOfProducts / v_PerPage); 
  128.          info "Total Product(s): " + v_TotalNumberOfProducts; 
  129.          info "Total Page(s): " + v_TotalNumberOfPages; 
  130.      } 
  131.      // 
  132.      // loop through products/items from response 
  133.      v_ItemNodePart = "Item"; 
  134.      v_ItemNodeName = v_ItemNodePart + "Array"; 
  135.      x_ItemNode = x_ResponseBody.subString(x_ResponseBody.indexOf("<" + v_ItemNodeName),x_ResponseBody.lastIndexOf(v_ItemNodeName) + v_ItemNodeName.length() + 1); 
  136.      l_Items = x_ItemNode.executeXPath("/" + v_ItemNodeName + "/" + v_ItemNodePart).toXmlList(); 
  137.      for each  x_Item in l_Items 
  138.      { 
  139.          // 
  140.          // build JSON row 
  141.          m_Item = Map(); 
  142.          m_Item.put("ItemID",x_Item.executeXPath("/" + v_ItemNodePart + "/ItemID/text()")); 
  143.          m_Item.put("ItemName",x_Item.executeXPath("/" + v_ItemNodePart + "/Title/text()")); 
  144.          m_Item.put("Price",x_Item.executeXPath("/" + v_ItemNodePart + "/SellingStatus/CurrentPrice/text()").toDecimal()); 
  145.          m_Item.put("CurrencyCode",x_Item.executeXPath("/" + v_ItemNodePart + "/SellingStatus/CurrentPrice/@currencyID").executeXPath("/currencyID/text()")); 
  146.          m_Item.put("QuantityAvailable",x_Item.executeXPath("/" + v_ItemNodePart + "/QuantityAvailable/text()").toDecimal()); 
  147.          m_Item.put("SKU",x_Item.executeXPath("/" + v_ItemNodePart + "/SKU/text()")); 
  148.          // 
  149.          v_Item_DateCreated = x_Item.executeXPath("/" + v_ItemNodePart + "/ListingDetails/StartTime/text()"); 
  150.          v_Item_DateCreated = if(!isnull(v_Item_DateCreated),v_Item_DateCreated.getPrefix(".").replaceFirst("T"," ",true).toTime(),zoho.currenttime).toString("yyyy-MM-dd HH:mm:ssZ"); 
  151.          m_Item.put("DateCreated",v_Item_DateCreated); 
  152.          // 
  153.          l_JsonProducts.add(m_Item); 
  154.          // 
  155.          // generate CSV row for monitoring purposes 
  156.          l_CsvFileRow = List(); 
  157.          l_CsvFileRow.add("\"'" + x_Item.executeXPath("/" + v_ItemNodePart + "/ItemID/text()") + "\""); 
  158.          l_CsvFileRow.add("\"" + x_Item.executeXPath("/" + v_ItemNodePart + "/Title/text()") + "\""); 
  159.          l_CsvFileRow.add(x_Item.executeXPath("/" + v_ItemNodePart + "/SellingStatus/CurrentPrice/text()")); 
  160.          l_CsvFileRow.add(x_Item.executeXPath("/" + v_ItemNodePart + "/SellingStatus/CurrentPrice/@currencyID").executeXPath("/currencyID/text()")); 
  161.          l_CsvFileRow.add(x_Item.executeXPath("/" + v_ItemNodePart + "/QuantityAvailable/text()")); 
  162.          l_CsvFileRow.add("\"" + x_Item.executeXPath("/" + v_ItemNodePart + "/SKU/text()") + "\""); 
  163.          l_CsvFileRow.add(v_Item_DateCreated); 
  164.          // 
  165.          v_CsvRow = l_CsvFileRow.toString(); 
  166.          l_CsvFileRows.add(v_CsvRow); 
  167.      } 
  168.      if(v_Page>=v_TotalNumberOfPages) 
  169.      { 
  170.          break; 
  171.      } 
  172.  } 
  173.  // 
  174.  m_Response.put("items",l_JsonProducts); 
  175.  //info m_Response; 
  176.  // 
  177.  // lets send the CSV and JSON by email 
  178.  if(l_JsonProducts.size()>0) 
  179.  { 
  180.      // 
  181.      // generate a CSV list for monitoring purposes 
  182.      v_CSVFilename = "active-ebay-products-" + zoho.currenttime.toString("yyyy-MM-dd-HH-mm-ss") + ".csv"; 
  183.      l_CsvFileRows.add("-----------------------------" + v_CSVFilename); 
  184.      // 
  185.      // usually \n works on some systems but this one works on systems that \n doesn't 
  186.      f_CSVFile = l_CsvFileRows.toString(zoho.encryption.urlDecode("%0A")).toFile(v_CSVFilename); 
  187.      // 
  188.      // just adding these in case 
  189.      v_JsonFilename = "active-ebay-products-" + zoho.currenttime.toString("yyyy-MM-dd-HH-mm-ss") + ".json"; 
  190.      f_JsonFile = m_Response.toString().toFile(v_JsonFilename); 
  191.      // 
  192.      // send via Email 
  193.      v_CountRows = l_CsvFileRows.size() - 2; 
  194.      v_Subject = l_JsonProducts.size() + " eBay Products Export & Comparison"; 
  195.      v_Message = "Hi there!<br /><br />Please find attached a log of <b>" + l_JsonProducts.size() + "</b> Product(s) from eBay that was exported on <b>" + zoho.currenttime.toString("EEEE, dd-MMM-yyyy") + "</b><br /><br />This is an automated email.  Please do not reply to it.<br /><br />Kind Regards,<br /><br />The Team"; 
  196.      sendmail 
  197.      [ 
  198.          from :zoho.adminuserid 
  199.          to :"Joel Lipman <This email address is being protected from spambots. You need JavaScript enabled to view it.>" 
  200.          subject :v_Subject 
  201.          message :v_Message 
  202.          Attachments :file:f_CSVFile,file:f_JsonFile 
  203.      ] 
  204.  } 
  205.  // 
  206.  return "Exported " + l_JsonProducts.size() + " product(s)"; 

Source(s):
Category: Zoho :: Article: 838

Credit where Credit is Due:


Feel free to copy, redistribute and share this information. All that we ask is that you attribute credit and possibly even a link back to this website as it really helps in our search engine rankings.

Disclaimer: Please note that the information provided on this website is intended for informational purposes only and does not represent a warranty. The opinions expressed are those of the author only. We recommend testing any solutions in a development environment before implementing them in production. The articles are based on our good faith efforts and were current at the time of writing, reflecting our practical experience in a commercial setting.

Thank you for visiting and, as always, we hope this website was of some use to you!

Kind Regards,

Joel Lipman
www.joellipman.com

Related Articles

Joes Revolver Map

Joes Word Cloud

Accreditation

Badge - Certified Zoho Creator Associate
Badge - Certified Zoho Creator Associate

Donate & Support

If you like my content, and would like to support this sharing site, feel free to donate using a method below:

Paypal:
Donate to Joel Lipman via PayPal

Bitcoin:
Donate to Joel Lipman with Bitcoin bc1qf6elrdxc968h0k673l2djc9wrpazhqtxw8qqp4

Ethereum:
Donate to Joel Lipman with Ethereum 0xb038962F3809b425D661EF5D22294Cf45E02FebF
© 2024 Joel Lipman .com. All Rights Reserved.